home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Compute! Gazette 1991 April
/
1991-04.d64
/
chaos 64
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-09-20
|
818b
|
31 lines
0 rem copyright 1991 compute publications intl ltd - all rights reserved
100 poke 53280,0:poke 53281,0
110 print"[147][155]":a$="clearing the bitmap...":a=len(a$)
120 for x=1 to 20-a/2:print" ";:next:printa$
130 for x=8192 to 16192:poke x,0:next
140 ax=1:ay=1:bx=319:by=1:cx=160:cy=199
150 poke 53265,(peek(53265) or 32)
160 poke 53270,((peek(53270) and 223) or 16)
170 poke 53272,((peek(53272) and 240) or 8)
180 print"[147]":for x=1024 to 2024:poke x,255:next
190 x=int((rnd(ti)*319)+1)
200 y=int((rnd(ti)*199)+1)
210 fori=1to10000
220 p1=ax:p2=ay:gosub360:p1=bx:p2=by:gosub360
230 p1=cx:p2=cy:gosub360
240 ifi>1thenx=kx
250 ifi>1theny=ky
260 p=int((rnd(ti)*6)+1)
270 if p=1thendx=ax:dy=ay
280 if p=2thendx=ax:dy=ay
290 if p=3thendx=bx:dy=by
300 if p=4thendx=bx:dy=by
310 if p=6thendx=cx:dy=cy
320 kx=(dx+x)/2:ky=(dy+y)/2
330 p1=kx:p2=ky:gosub360
340 if i=10000thenend
350 next i
360 bt=8192+int(p2/8)*320+int(p1/8)*8+(p2 and 7)
370 poke bt,peek(bt) or 2^(7-(p1 and 7))
380 return